How to find the longest row in a file ?

xavier · Dec 14, 2005#12005-12-14T16:35+00:00

Bego · Dec 14, 2005#22005-12-14T18:59+00:00

Hi Xavier,

I think you won't get lucky with UE-macros here, cause you need a variable here (or a special trick I don't know), but there is a workaround.

Take this vb-Script "longestline.vbs":

Code: Select all

Dim objFileSystem, objInputFile
Dim strOutputFile, inputData, strData, strLine, i

Const MYFILENAME = "c:\test.txt"

Const OPEN_FILE_FOR_READING = 1

Set objFileSystem = CreateObject("Scripting.fileSystemObject")
Set objInputFile = objFileSystem.OpenTextFile(MYFILENAME , OPEN_FILE_FOR_READING)

inputData = Split(objInputFile.ReadAll, vbNewline)

i=0
For each strData In inputData
    'WScript.Echo strData & len(strData)
    if len(strData) > i then
       i = len(strData)
       strLine = strData
    end if
Next

objInputFile.Close
Set objFileSystem = Nothing

WScript.Echo  "Longest line is: " & strLine

WScript.Quit(0)

and use your filename for MYFILENAME.
You can customize this script EASILY with filename as parameter so you can call it via UE-toolbar (!).

rds Bego

xavier · Dec 15, 2005#32005-12-15T15:49+00:00

Thanks a lot Bego.

It works well and it's fast (500000 rows analysed in 10s).

I did a version that I can call from UE:

Command Line: MaxRow.vbs %F
Working Directory: %p
Menu Item Name: Get max row

Here is the version of MaxRow.vbs:

Code: Select all

Dim objFileSystem, objInputFile
Dim strOutputFile, inputData, strData, strLine, i
Dim ArgObj, strFilename

Const OPEN_FILE_FOR_READING = 1

Set ArgObj = WScript.Arguments 
strFilename = ArgObj(0) 

Set objFileSystem = CreateObject("Scripting.fileSystemObject")
Set objInputFile = objFileSystem.OpenTextFile(strFilename , OPEN_FILE_FOR_READING)

inputData = Split(objInputFile.ReadAll, vbNewline)

i=0
For each strData In inputData
    'WScript.Echo strData & len(strData)
    if len(strData) > i then
       i = len(strData)
       strLine = strData
    end if
Next

objInputFile.Close
Set objFileSystem = Nothing

WScript.Echo  "Longest line is: " & strLine & vbCrlf & vbCrlf & "Nb characters: " & Len(strLine)

WScript.Quit(0)

Bego · Dec 15, 2005#42005-12-15T16:48+00:00

Hi Xavier,

jup, thats what I meant

Anyway, one hast to say that this solution is limited to PC-files.

If working on a remote FTP-file, it fails.
(But I dont care about it

Have fun, Bego