Okay, here is the macro which should do this job on your large files. Good that you have mentioned that because I would have written the macro different when the files are not so big.

File 1 with the phone numbers only must have the focus. File 2 is also already open. No other file should be open.

First the macro trims all trailing spaces in file 1 (for security) and inserts a new line at the end of the file with the special marker character » and then copies whole content of file 1 to clipboard 9 and pastes it at top of file 2. This is done to avoid window switching which normally decrease macro execution speed. Hopefully size of file 1 is not too big for clipboard copying.

Now in file 2 a loop is executed until the marker character is found at start of a line.

In the loop first the current line is marked with character # and the phone number is selected and copied to clipboard 9. Next a find for this phone number with a following comma is executed.

If this search string is found the comma and the following domain name is copied to user clipboard 8 and with a find upwards with clipboard 9 reactived the cursor is moved back to the current phone number from file 1. There the comma and the domain name is appended to the line and the line mark remains.

If search for phone number with following comma was not successful, the line mark is removed.

Last command moves cursor down to next phone number from file 1 or the special marker character.

After the loop has finished the macro selects the maybe modified content from file 1 in file 2, cuts it to user clipboard 9 and pastes it over still existing selection in file 1. So file 2 was temporarily modified, but now contains the same content as before start of the macro.

In file 1 the last line with the special marker character is deleted, the cursor is positioned back to top and the 2 used clipboards are cleared to free memory.

The macro property Continue if a Find with Replace not found must be checked for this macro.

InsertMode
ColumnModeOff
HexOff
TrimTrailingSpaces
Bottom
IfColNum 1
"»
"
Else
"
»
"
EndIf
SelectAll
Clipboard 9
Copy
NextWindow
Top
Paste
Top
Loop
IfCharIs "»"
ExitLoop
EndIf
"#"
StartSelect
Key END
Copy
EndSelect
Find "^c,"
IfFound
Key LEFT ARROW
StartSelect
Key END
Clipboard 8
Copy
EndSelect
Clipboard 9
Find Up "#^c"
Key LEFT ARROW
Key RIGHT ARROW
Clipboard 8
Paste
Clipboard 9
Key HOME
Else
Key HOME
Key DEL
EndIf
Key DOWN ARROW
EndLoop
Key DOWN ARROW
SelectToTop
Cut
PreviousWindow
Paste
Key UP ARROW
DeleteLine
Top
ClearClipboard
Clipboard 8
ClearClipboard
Clipboard 0

Because Christmas is soon coming, here is a second macro which does the same as above but uses window switching. You can use this one, if file 1 is also very large. I would be really interested in which version is faster. Can you run both macros on the same files, determine the execution time and post it?

The macro property Continue if a Find with Replace not found must be checked for this macro too.

InsertMode
ColumnModeOff
HexOff
TrimTrailingSpaces
Bottom
IfColNum 1
"»
"
Else
"
»
"
EndIf
Top
NextWindow
Top
PreviousWindow
Loop
IfCharIs "»"
ExitLoop
EndIf
"#"
StartSelect
Key END
Copy
EndSelect
NextWindow
Find "^c,"
IfFound
Key LEFT ARROW
StartSelect
Key END
Copy
EndSelect
Top
PreviousWindow
Key LEFT ARROW
Key RIGHT ARROW
Paste
Key HOME
Else
PreviousWindow
Key HOME
Key DEL
EndIf
Key DOWN ARROW
EndLoop
DeleteLine
Top
ClearClipboard
Clipboard 0

And here is again the macro above, but now without the special marker character because now IfEof is used. This will not work if file 1 is a Unicode file because UltraEdit v12.20b does not correctly identify end of file on Unicode files. So the marker character in a new line at end of the file used in the macro above is my workaround to run a macro to end of a file when I don't know the file format (Unicode or ASCII).

The macro property Continue if a Find with Replace not found must be checked for this macro too.

InsertMode
ColumnModeOff
HexOff
TrimTrailingSpaces
Bottom
IfColNumGt 1
InsertLine
EndIf
Top
NextWindow
Top
PreviousWindow
Loop
IfEof
ExitLoop
EndIf
"#"
StartSelect
Key END
Copy
EndSelect
NextWindow
Find "^c,"
IfFound
Key LEFT ARROW
StartSelect
Key END
Copy
EndSelect
Top
PreviousWindow
Key LEFT ARROW
Key RIGHT ARROW
Paste
Key HOME
Else
PreviousWindow
Key HOME
Key DEL
EndIf
Key DOWN ARROW
EndLoop
Top
ClearClipboard
Clipboard 0

A database program would do this job really much faster than UltraEdit.

Have you understand and tried my macros? Which one is faster?

Because of your very large files it is maybe really better to use macro 2 or 3. The modified first file is not saved at the end, so you can delete all remaining lines not marked with a # at start of the line, then remove the # character itself from start of all lines and save the file with a new name.

List 2 are 86 files - no problem. Use the old DOS command copy to copy all 86 files together to a REALLY big single file - see Appending text files and Want to combine many files into one file - and then use one of my macros. You should also read in help of UltraEdit the page with the title Large File Handling and configure UltraEdit accordingly.