The file
batch_file.txt can be downloaded from the power tip page. It contains the lines:
Code: Select all
#Location of config and autoexec files
set CONFIGSAS=<path & file to your config file>
set AUTOEXECSAS= <path & file for your autoexec file>
#Location of sas.exe. Note %1 & %2 parms will be set by UltraEdit Tool.
#For 64 bit, use: C:\Program Files\SAS\SASFoundation\9.2(32-bit)\sas.exe
Set EXESAS= <path & file to sas.exe>
"%EXESAS%" ^
-CONFIG "%CONFIGSAS%" ^
-autoexec "%AUTOEXECSAS%" -sysin %1 -log %2 –nodms
is used instead of
rem used for comment lines.
There mixed somebody Windows batch with Linux/Mac bash syntax as
# is definitely not interpreted by Windows command processor
cmd.exe as comment line. There should be used the command
rem (or the invalid label
:: which I do not recommend for usage in a batch file).
Mistake 2: The character left to option
nodms is not a hyphen-minus character.
The character left to option
nodms is not a
hyphen-minus character with hexadecimal code value 2D, but a
Windows-1252 encoded
en-dash with hexadecimal value 96 (hexadecimal 2012 in Unicode) which is interpreted with
code page 437 or
code page 850 as
Latin capital letter U with circumflex.
That wrong character is responsible for the error message: ERROR: Unrecognized SAS option name
ÛNODMS.
Mistake 3: The ampersand
& is interpreted as AND operator by
cmd.exe outside a double quoted string.
So please use in your batch file:
Code: Select all
@rem Location of config and autoexec files
set CONFIGSAS=C:\Program Files\SASHome\SASFoundation\9.4\sasv9.cfg
set AUTOEXECSAS=%UserProfile%\OneDrive - The University ...\...\Develop Run and Debug your SAS Programs in UltraEdit_files\autoexec.sas
@rem Location of sas.exe. Note %1 and %2 parms will be set by UltraEdit Tool.
set EXESAS=C:\Program Files\SASHome\SASFoundation\9.4\sas.exe
"%EXESAS%" -CONFIG "%CONFIGSAS%" -autoexec "%AUTOEXECSAS%" -sysin %1 -log %2 -nodms
I does not really make sense to use a multi-line command line here with usage of
^ to escape the line terminations. That just makes processing of the batch file a bit slower.
It makes also no real sense for me to define three environment variables with the full qualified file names of the SAS executable, config and autoexec files which are used only once in the batch file.
And if the log file should be created always in the directory of the file being processed by SAS with file extension .log instead of file extension of active file in UltraEdit, there is no need to use
"%p%n.log" in the UltraEdit tool configuration to pass the name of the active file with path with file extension .log to the batch file. It is easier to use in this case in the batch file a single line with:
Code: Select all
"C:\Program Files\SASHome\SASFoundation\9.4\sas.exe" -CONFIG "C:\Program Files\SASHome\SASFoundation\9.4\sasv9.cfg" -autoexec "%UserProfile%\OneDrive - The University ...\...\Develop Run and Debug your SAS Programs in UltraEdit_files\autoexec.sas" -sysin %1 -log "%~dpn1.log" -nodms
Well, in real a batch file would not be needed at all. The UltraEdit tool configuration could contain this command line with
%1 being replaced in tool configuration by
"%f" and
"%~dpn1.log" by
"%p%n.log" resulting in the UltraEdit tool configuration command:
Code: Select all
"C:\Program Files\SASHome\SASFoundation\9.4\sas.exe" -CONFIG "C:\Program Files\SASHome\SASFoundation\9.4\sasv9.cfg" -autoexec "%UserProfile%\OneDrive - The University ...\...\Develop Run and Debug your SAS Programs in UltraEdit_files\autoexec.sas" -sysin "%f" -log "%p%n.log" -nodms
However, if a batch file processed by
cmd.exe should be used just to run
sas.exe which could be done also directly by UltraEdit, a better batch file code would be:
Code: Select all
@echo off
setlocal EnableExtensions DisableDelayedExpansion
rem Definition of the full qualified file names of config and autoexec files.
set "CONFIGSAS=full path and file to your config file"
set "AUTOEXECSAS=full path and file for your autoexec file"
rem Definition of the full qualified file name of sas.exe.
rem For 64 bit use: C:\Program Files\SAS\SASFoundation\9.2(32-bit)\sas.exe
set "EXESAS=full path to\sas.exe"
rem Note: %1 and %2 reference the parameters passed by the UltraEdit tool
rem to this batch file. The second argument is optional and can be omitted
rem in the UltraEdit tool configuration.
if "%~1" == "" echo ERROR: File to process by SAS is not specified.& goto :EOF
set "LogFile=%~2"
if not defined LogFile set "LogFile=%~dpn1.log"
@echo on
"%EXESAS%" -CONFIG "%CONFIGSAS%" -autoexec "%AUTOEXECSAS%" -sysin %1 -log "%LogFile%" -nodms
@endlocal
I will inform IDM support by email about the serious mistakes made by the contributor Keith Adams to get them all fixed.
I have the favor to ask you for running a command in a Windows command prompt window and tell me the output of the command.
Code: Select all
%SystemRoot%\System32\reg.exe QUERY "HKLM\Software\Microsoft\Windows\CurrentVersion\App Paths\sas.exe" /ve
What is output on running this command line in a command prompt window?
There can be output the error message:
Code: Select all
ERROR: The system was unable to find the specified registry key or value.
But there could be output also the default string value of the queried registry key which would be the
C:\Program Files\SASHome\SASFoundation\9.4\sas.exe (or the short 8.3 file name) in your case on SAS being registered during installation as recommended by Microsoft according to the documentation about
Application Registration. I could suggest a batch file to use which can find out itself the full qualified file name of
sas.exe on being registered as recommended by Microsoft.
